#! /usr/bin/env perl

# Default module imports
use strict;                 # Altijd goed om strict en warnings te gebruiken
use warnings;
use v5.11;                  # Gebruik v5.11 voor onder andere de 'say' functie

# Specifieke module imports voor dit script
use Data::Dumper;           # Handig voor debuggen, hiermee kun je complexe datastructuren mooi printen
use Config::Simple;         # Om makkelijk configuratiebestanden te kunnen lezen
use Time::Piece;            # Voor het werken met datums en tijden
use FindBin;                # Om het pad van het script te kunnen gebruiken, handig voor het vinden van config bestanden en libraries
use LWP::UserAgent;         # Voor het maken van HTTP requests
use JSON;                   # Voor het werken met JSON data, zoals de responses van de Microsoft Graph API


# Initialisatie van de configuratie
my %config;                # Hash om de configuratie in op te slaan
# Lees de configuratie uit azure.cfg, als dat niet lukt, geef een foutmelding en stop het script
Config::Simple->import_from("$FindBin::Bin/azure.cfg",\%config) or die("No config: $!"); 

# Maak een nieuwe UserAgent aan voor het maken van HTTP requests
my $ua = LWP::UserAgent->new;   

# De URL voor het ophalen van een access token van de Microsoft Identity Platform
# Gebruik hier de login endpoint.
my $token_url = $config{'LOGIN_ENDPOINT'}."/".$config{'TENANT_ID'}."/oauth2/token";

# Bereid een request voor om een access token op te halen van de Microsoft Identity Platform
my $token_request = HTTP::Request->new(
    POST => $token_url,
    [
        'Accept'        =>  '*/*',
        'User-Agent'    =>  'Perl LWP',
        'Content-Type'  =>  'application/x-www-form-urlencoded'
    ],
    "grant_type=client_credentials".
    "&client_id="    . $config{'APP_ID'} . 
    "&client_secret=". $config{'APP_PASS'} . 
    "&scope="        . $config{'GRAPH_ENDPOINT'} . "/.default" .
    "&resource="     . $config{'GRAPH_ENDPOINT'},
);

# Execute de request met de LWP UserAgent
my $result = $ua->request($token_request);

# Verwerk het resultaat
my $access_token;
if ($result->is_success){
    my $reply = decode_json($result->decoded_content);
    $access_token = $reply->{'access_token'};
}else{
    print Dumper $result;
    die $result->status_line;
}

# We hebben nu een access token, 
# dat kunnen we gebruiken om API calls te maken naar de Microsoft Graph API

# Stel een URL samen voor een API call, laten we de groepen weer opvragen als voorbeeld
# Pagina grootte is 1, en we selecteren alleen de id en displayName van de groepen om het overzichtelijk te houden
my $api_url = $config{'GRAPH_ENDPOINT'}.'/v1.0/groups?$top=1&$select=id,displayName';
# Bereid een request voor om de groepen op te halen, gebruik het access token in de Authorization header
my $api_request = HTTP::Request->new(
    GET => $api_url,
    [
        'Accept'        =>  'application/json',
        'User-Agent'    =>  'Perl LWP',
        'Authorization' =>  "Bearer $access_token"
    ],
); 

# Execute de API request
my $api_result = $ua->request($api_request);
# Verwerk het resultaat van de API call
if ($api_result->is_success){
    my $api_reply = decode_json($api_result->decoded_content);
    print Dumper $api_reply; # Print de response van de API call, dit zal een lijst van groepen bevatten
}else{
    print Dumper $api_result;
    die $api_result->status_line;
}

{
          '@odata.nextLink' => 'https://graph.microsoft.com/v1.0/groups?$top=1&$select=id%2cdisplayName&$skiptoken=[skip token]',
          'value' => [
                       {
                         'id' => '[group id]',
                         'displayName' => '[group displayName]'
                       }
                     ],
          '@odata.context' => 'https://graph.microsoft.com/v1.0/$metadata#groups(id,displayName)'
        }